Amsab-ISG Linked Data

Public Linked Data and SPARQL services

This service provides human-readable and machine-readable access to Linked Data published by Amsab-ISG.

Datasets

Brigades

Linked Data concerning volunteers in the International Brigades.

Open dataset

Services

SPARQL query interface

Explore the data interactively using YASGUI.

Open YASGUI

SPARQL endpoint

Applications can query the public SPARQL endpoint.

https://data.amsab.be/sparql

Dataset downloads

Browse bulk RDF exports and related download files.

Browse downloads

Explore the Brigades dataset

These examples demonstrate how the Brigades dataset can be queried. Click Open in YASGUI to load a query into the SPARQL editor, then press Run.

1. Find people by family name

Find people whose family name contains Abelshausen.

Open in YASGUI
Show SPARQL query 
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

SELECT ?person ?firstName ?familyName
WHERE {
    GRAPH <https://data.amsab.be/graph/brigades> {
        ?person foaf:familyName ?familyName .

        OPTIONAL {
            ?person foaf:firstName ?firstName .
        }

        FILTER(
            CONTAINS(
                LCASE(STR(?familyName)),
                "abelshausen"
            )
        )
    }
}
ORDER BY ?familyName ?firstName

2. People who arrived in 1937

Retrieve people whose recorded start date begins with 1937.

Open in YASGUI
Show SPARQL query 
PREFIX schema:  <http://schema.org/>
PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT ?person ?title ?startDate
WHERE {
    GRAPH <https://data.amsab.be/graph/brigades> {
        ?person schema:startDate ?startDate .

        OPTIONAL {
            ?person dcterms:title ?title .
        }

        FILTER(
            STRSTARTS(
                STR(?startDate),
                "1937"
            )
        )
    }
}
ORDER BY ?startDate ?title

3. Count people by nationality

Show recorded nationalities and count the number of people associated with each.

Open in YASGUI
Show SPARQL query 
PREFIX schema: <http://schema.org/>

SELECT
    ?nationality
    (COUNT(DISTINCT ?person) AS ?people)
WHERE {
    GRAPH <https://data.amsab.be/graph/brigades> {
        ?person schema:nationality ?nationality .
    }
}
GROUP BY ?nationality
ORDER BY DESC(?people)

4. Search political or organizational affiliations

Find records where an organizational affiliation contains the word communist.

Open in YASGUI
Show SPARQL query 
PREFIX schema:  <http://schema.org/>
PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT ?person ?title ?organisation
WHERE {
    GRAPH <https://data.amsab.be/graph/brigades> {
        ?person schema:memberOf ?organisation .

        OPTIONAL {
            ?person dcterms:title ?title .
        }

        FILTER(
            CONTAINS(
                LCASE(STR(?organisation)),
                "communist"
            )
        )
    }
}
ORDER BY ?title

5. Find members of the 14th Brigade

Find people whose recorded military unit contains 14th Brigade.

Open in YASGUI
Show SPARQL query 
PREFIX schema:  <http://schema.org/>
PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT ?person ?title ?unit
WHERE {
    GRAPH <https://data.amsab.be/graph/brigades> {
        ?person schema:subOrganization ?unit .

        OPTIONAL {
            ?person dcterms:title ?title .
        }

        FILTER(
            CONTAINS(
                LCASE(STR(?unit)),
                "14th brigade"
            )
        )
    }
}
ORDER BY ?title

Linked Data URIs

Persistent resource identifier https://data.amsab.be/id/{guid}
Human-readable representation https://data.amsab.be/doc/{guid}
Machine-readable representation https://data.amsab.be/rdf/{guid}
Brigades dataset https://data.amsab.be/brigades
Brigades named graph https://data.amsab.be/graph/brigades

The graph identifier redirects to the human-readable Brigades dataset page when opened in a browser.

About

Amsab-ISG publishes cultural heritage and research data as Linked Data. Persistent resource identifiers are kept separate from their human-readable and machine-readable representations.